feat(sirius): enable impermanence

.sops.yaml

@@ -4,6 +4,7 @@ keys:
 
   - &hosts
     - &sirius age18hepvvp3nw9ram6usxc8rvpxed2pye0knqx0zutqgxeu35k745vqyxfphz
+    - &arcturus age1huqa3hc7wcxk4dpelrzny437nzrx4fnll3d8g9ahznzk268yju5qufapxy
 
 creation_rules:
   - path_regex: hosts/sirius/secrets.yaml$
@@ -11,3 +12,8 @@ creation_rules:
       - age:
           - *tux
           - *sirius
+  - path_regex: hosts/arcturus/secrets.yaml$
+    key_groups:
+      - age:
+          - *tux
+          - *arcturus

flake.lock

@@ -112,6 +112,26 @@
         "type": "github"
       }
     },
+    "cyber-tux": {
+      "inputs": {
+        "nixpkgs": [
+          "nixpkgs"
+        ]
+      },
+      "locked": {
+        "lastModified": 1739652548,
+        "narHash": "sha256-J4mL4DyRFTsEKlratZsbC9tm2i6Mzr6dEhetKk4jABM=",
+        "ref": "refs/heads/main",
+        "rev": "4ada9e2f0d3b6639627601d3f06128c953c2b446",
+        "revCount": 11,
+        "type": "git",
+        "url": "ssh://git@github.com/tuxdotrs/cyber-tux.git"
+      },
+      "original": {
+        "type": "git",
+        "url": "ssh://git@github.com/tuxdotrs/cyber-tux.git"
+      }
+    },
     "deploy-rs": {
       "inputs": {
         "flake-compat": "flake-compat_2",
@@ -1236,6 +1256,7 @@
     "root": {
       "inputs": {
         "awww": "awww",
+        "cyber-tux": "cyber-tux",
         "deploy-rs": "deploy-rs",
         "disko": "disko",
         "flake-parts": "flake-parts",

flake.nix

@@ -29,6 +29,11 @@
       inputs.nixpkgs.follows = "nixpkgs";
     };
 
+    cyber-tux = {
+      url = "git+ssh://git@github.com/tuxdotrs/cyber-tux.git";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
     wezterm-flake = {
       url = "github:wez/wezterm/main?dir=nix";
       inputs.nixpkgs.follows = "nixpkgs";

modules/flake/overlays.nix

@@ -7,6 +7,7 @@
     modifications = final: prev: {
       tnvim = inputs.tnvim.packages.${prev.stdenv.hostPlatform.system}.default;
       tpanel = inputs.tpanel.packages.${prev.stdenv.hostPlatform.system}.default;
+      cyber-tux = inputs.cyber-tux.packages.${prev.stdenv.hostPlatform.system}.default;
       ags = inputs.tpanel.packages.${prev.stdenv.hostPlatform.system}.ags.default;
       wezterm-git = inputs.wezterm-flake.packages.${prev.stdenv.hostPlatform.system}.default;
       hyprland-git = inputs.hyprland.packages.${prev.stdenv.hostPlatform.system};

modules/hosts/arcturus/config.nix

@@ -0,0 +1,89 @@
+{ config, ... }:
+{
+  flake.modules.nixos.arcturus =
+    {
+      pkgs,
+      hostName,
+      userName,
+      ...
+    }@innerArgs:
+    {
+      imports = with config.flake.modules.nixos; [
+        boot
+        hardware
+        networking
+        virtualisation
+        services
+      ];
+
+      tnix = {
+        boot.secure-boot.enable = true;
+        boot.impermanence.enable = true;
+        networking.openssh.enable = true;
+
+        services = {
+          cyber-tux = {
+            enable = true;
+            environmentFile = innerArgs.config.sops.secrets.discord-token.path;
+          };
+        };
+
+        virtualisation = {
+          docker.enable = true;
+        };
+      };
+
+      sops.secrets = {
+        tux-password = {
+          sopsFile = ./secrets.yaml;
+          neededForUsers = true;
+        };
+
+        discord-token = {
+          sopsFile = ./secrets.yaml;
+        };
+
+        gemini-api-key = {
+          sopsFile = ./secrets.yaml;
+          owner = userName;
+        };
+
+        openrouter-api-key = {
+          sopsFile = ./secrets.yaml;
+          owner = userName;
+        };
+
+        opencode-go-api-key = {
+          sopsFile = ./secrets.yaml;
+          owner = userName;
+        };
+      };
+
+      # --- Networking ---
+      networking = {
+        hostName = hostName;
+        networkmanager = {
+          enable = true;
+          wifi.backend = "iwd";
+        };
+        wireless.iwd = {
+          enable = true;
+          settings = {
+            Network = {
+              EnableIPv6 = true;
+            };
+            Settings = {
+              AutoConnect = true;
+            };
+          };
+        };
+        firewall.enable = false;
+      };
+
+      environment.systemPackages = with pkgs; [
+        nvtopPackages.full
+      ];
+
+      system.stateVersion = "26.05";
+    };
+}

modules/hosts/arcturus/default.nix

@@ -0,0 +1,23 @@
+{
+  inputs,
+  config,
+  ...
+}:
+let
+  hostName = "arcturus";
+  userName = "tux";
+  userEmail = "t@tux.rs";
+  system = "x86_64-linux";
+  unstable = true;
+  nixpkgs = if unstable then inputs.nixpkgs else inputs.nixpkgs-stable;
+in
+{
+  flake.nixosConfigurations."${hostName}" = nixpkgs.lib.nixosSystem {
+    inherit system;
+    specialArgs = { inherit hostName userName userEmail; };
+    modules = [
+      config.flake.modules.nixos.core
+      config.flake.modules.nixos.${hostName}
+    ];
+  };
+}

modules/hosts/arcturus/disko.nix

@@ -0,0 +1,74 @@
+{ inputs, ... }:
+{
+  flake.modules.nixos.arcturus =
+    { config, lib, ... }:
+    let
+      hasOptinPersistence = config.tnix.boot.impermanence.enable;
+    in
+    {
+      imports = [
+        inputs.disko.nixosModules.disko
+      ];
+
+      disko.devices.disk.primary = {
+        device = "/dev/nvme0n1";
+        type = "disk";
+        content = {
+          type = "gpt";
+          partitions = {
+            ESP = {
+              size = "1G";
+              type = "EF00";
+              content = {
+                type = "filesystem";
+                format = "vfat";
+                mountpoint = "/boot";
+                mountOptions = [
+                  "defaults"
+                  "umask=0077"
+                ];
+              };
+            };
+            root = {
+              size = "100%";
+              type = "8300";
+              content = {
+                type = "btrfs";
+                # Base subvolumes that always exist
+                subvolumes = {
+                  "/root" = {
+                    mountOptions = [
+                      "compress=zstd"
+                      "noatime"
+                      "space_cache=v2"
+                    ];
+                    mountpoint = "/";
+                  };
+                  "/nix" = {
+                    mountOptions = [
+                      "compress=zstd"
+                      "noatime"
+                      "noacl"
+                      "space_cache=v2"
+                    ];
+                    mountpoint = "/nix";
+                  };
+                }
+                # Conditionally merge /persist only when impermanence is enabled
+                // lib.optionalAttrs hasOptinPersistence {
+                  "/persist" = {
+                    mountOptions = [
+                      "compress=zstd"
+                      "noatime"
+                      "space_cache=v2"
+                    ];
+                    mountpoint = "/persist";
+                  };
+                };
+              };
+            };
+          };
+        };
+      };
+    };
+}

modules/hosts/arcturus/hardware.nix

@@ -0,0 +1,32 @@
+{
+  flake.modules.nixos.arcturus =
+    {
+      config,
+      lib,
+      ...
+    }:
+    {
+      boot.initrd.availableKernelModules = [
+        "nvme"
+        "xhci_pci"
+        "ahci"
+        "usbhid"
+        "usb_storage"
+        "sd_mod"
+      ];
+      boot.initrd.kernelModules = [ ];
+      boot.kernelModules = [ "kvm-amd" ];
+      boot.extraModulePackages = [ ];
+
+      # Enables DHCP on each ethernet and wireless interface. In case of scripted networking
+      # (the default) this is the recommended approach. When using systemd-networkd it's
+      # still possible to use this option, but it's recommended to use it in conjunction
+      # with explicit per-interface declarations with `networking.interfaces.<interface>.useDHCP`.
+      networking.useDHCP = lib.mkDefault true;
+      # networking.interfaces.eno1.useDHCP = lib.mkDefault true;
+      # networking.interfaces.wlp10s0f3u2i2.useDHCP = lib.mkDefault true;
+
+      nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";
+      hardware.cpu.amd.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
+    };
+}

modules/hosts/arcturus/home.nix

@@ -0,0 +1,6 @@
+{ ... }:
+{
+  flake.modules.homeManager.arcturus = {
+    home.stateVersion = "26.05";
+  };
+}

modules/hosts/arcturus/secrets.yaml

@@ -0,0 +1,29 @@
+tux-password: ENC[AES256_GCM,data:eXg28pYQjIi5iPh4oHBOvIYQReM92T79uty/O461mEoLB8awr8ikq3RM7Mux3jZKM+Fk/Ow3NNG0F/154dZentodr1uvy9gD1g==,iv:nQevOumENveBMuiYMJF0OokORyjZCpR8ahTfOuj2Dzo=,tag:64zz8eVuw1OwTltfAUwWSg==,type:str]
+discord-token: ENC[AES256_GCM,data:uzxkrNRRplL/1MfvPZ/EL+I8UACuZQBHZ95BSHuxW0nBjxhr2F89D2BXTcKOBI9qO6uMjK5WBtWzSOw3y9EsngTTm/youIdkrIDLP3r/tkpOkLa/VjM=,iv:OxzFa0nEInV5uxgQFww11ZE1NorH5q130Tgp/6l9uOE=,tag:g4U9wLhPAkz72ktbQ8KrSg==,type:str]
+gemini-api-key: ENC[AES256_GCM,data:gLZSoYTdKY+rwIpYiXvN9n9PGkUD6q8Oe7dHnYkjEjwDf5qpjubg,iv:ySoNgQWTu9DjvbashF4ulyYP8fJUl4yrCTeBQ0jrGmw=,tag:FctubsQv50AP78JvTb9bpQ==,type:str]
+openrouter-api-key: ENC[AES256_GCM,data:6xONCl9lqOoO7b4CEyCz9607tICDUAkpglRjGS5nYq2ppg2UKqYTrWD1BGCA5Xfs/CWskniVhoNG3vscjKiYCCh9gbM6aqdmTQ==,iv:7Iwc9t00HOOBjA7URXcUO41badqYyJCkFHM/uPkLFxY=,tag:Cl39kitr2e0//HVwAdsdUQ==,type:str]
+opencode-go-api-key: ENC[AES256_GCM,data:dmeRKn7TWHnqvpyPQpcEG6yHTb2bRby/rh10ytL0jHj5R+lRmNVdmqUF92GTznY9vEaB6ZYCJecWhpm8g4upNfOWBg==,iv:9UMJpAlD8gpcNiN+liu3nawoAZQKapEg7sCp561N9E8=,tag:OZlASpOa5BQaQwFWjoLCRw==,type:str]
+sops:
+    age:
+        - recipient: age14vktfes95f33vuefwnmuvryas7az04u76dsgyhfvsx73czkvmp2q7njkl4
+          enc: |
+            -----BEGIN AGE ENCRYPTED FILE-----
+            YWdlLWVuY3J5cHRpb24ub3JnL3YxCi0+IFgyNTUxOSA3Qkh0cmdHNGJTYmFNUFZW
+            c244RjlyNjlrSWh1bG1IRFFFeFZZVzhaYVdBCmd1N3JNS0IzWDlUMUJSM0pYdi9L
+            MzlHRk1pZ1hqaVdIYUQwczh2VDVtZE0KLS0tIEtRYWF6V0I3eDBZSnVmZ2R5S0Z5
+            Z3hhRitmdEwxbzcrS0cwNTZVK1lXYlUKSFfKk7JGzxRq9weL4NKJqfmAige2O+1T
+            59PvEFKvvkGb6ajkzwTw0lB3UFzly6FuTnbSLY9r+oT9AMbxLoKdcQ==
+            -----END AGE ENCRYPTED FILE-----
+        - recipient: age1huqa3hc7wcxk4dpelrzny437nzrx4fnll3d8g9ahznzk268yju5qufapxy
+          enc: |
+            -----BEGIN AGE ENCRYPTED FILE-----
+            YWdlLWVuY3J5cHRpb24ub3JnL3YxCi0+IFgyNTUxOSBOYlZiak1CSW1NSGt5QTRi
+            RjlUeG5EODVkTVJDY1RrZXJ6OU5NQ0RIOG5jCnJxZ1R6MmlGWXY2SmtaY1pQSWdZ
+            UWp3L2h6c0k0MVpubE9BRSswUEk3ZkkKLS0tIGN4Zm1tcHBiKzAyYWNHVktVZmpU
+            V3h4dUZLcktrTUZvUm44eVZOWEl4VmMKMTvajoWcktb4jVIP4HyzQiR41Wg8Gdqi
+            TLKEYsPQgOJ7s8P9gw2uPUY6HRz86CtiC6EbO27u0+8BbI85x1QScg==
+            -----END AGE ENCRYPTED FILE-----
+    lastmodified: "2026-05-08T19:38:01Z"
+    mac: ENC[AES256_GCM,data:G6Klq53VRWgDZDM4aDi0vbs87nvM90eH4e9XZNDMtSdrlf/60Lo2/0qp8kAsuKjf6OC5ThEMSP6h0nWrCZryVGP32b6BCMSUcecFm1rdCP3s64iPUlx/5UeT1dbPG1MPfV+mjO2/43dM9Nkmov7WiFrQ7NNJluvwu/7z6v6hEsQ=,iv:qbesEfb/9hqdwzSvNI0p6/QuGoQQ14ZPwK2S6op9o3g=,tag:5B2cnkWiEeg+GOrtK4H82A==,type:str]
+    unencrypted_suffix: _unencrypted
+    version: 3.12.2

modules/hosts/sirius/config.nix

@@ -8,9 +8,9 @@
       ...
     }:
     {
-
       imports = with config.flake.modules.nixos; [
         boot
+        hardware
         networking
         desktop
         virtualisation
@@ -18,6 +18,7 @@
 
       tnix = {
         boot.secure-boot.enable = true;
+        boot.impermanence.enable = true;
         networking.openssh.enable = true;
 
         virtualisation = {
@@ -56,9 +57,6 @@
         };
       };
 
-      # --- Boot ---
-      boot.kernelPackages = pkgs.linuxKernel.packages.linux_zen;
-
       # --- Networking ---
       networking = {
         hostName = hostName;

modules/hosts/sirius/disko.nix

@@ -0,0 +1,82 @@
+{ inputs, ... }:
+{
+  flake.modules.nixos.sirius =
+    { config, lib, ... }:
+    let
+      hasOptinPersistence = config.tnix.boot.impermanence.enable;
+    in
+    {
+      imports = [
+        inputs.disko.nixosModules.disko
+      ];
+
+      disko.devices.disk.primary = {
+        device = "/dev/nvme1n1";
+        type = "disk";
+        content = {
+          type = "gpt";
+          partitions = {
+            ESP = {
+              size = "1G";
+              type = "EF00";
+              content = {
+                type = "filesystem";
+                format = "vfat";
+                mountpoint = "/boot";
+                mountOptions = [
+                  "defaults"
+                  "umask=0077"
+                ];
+              };
+            };
+            swap = {
+              size = "70G";
+              content = {
+                type = "swap";
+                discardPolicy = "both";
+                resumeDevice = true;
+              };
+            };
+            root = {
+              size = "100%";
+              type = "8300";
+              content = {
+                type = "btrfs";
+                # Base subvolumes that always exist
+                subvolumes = {
+                  "/root" = {
+                    mountOptions = [
+                      "compress=zstd"
+                      "noatime"
+                      "space_cache=v2"
+                    ];
+                    mountpoint = "/";
+                  };
+                  "/nix" = {
+                    mountOptions = [
+                      "compress=zstd"
+                      "noatime"
+                      "noacl"
+                      "space_cache=v2"
+                    ];
+                    mountpoint = "/nix";
+                  };
+                }
+                # Conditionally merge /persist only when impermanence is enabled
+                // lib.optionalAttrs hasOptinPersistence {
+                  "/persist" = {
+                    mountOptions = [
+                      "compress=zstd"
+                      "noatime"
+                      "space_cache=v2"
+                    ];
+                    mountpoint = "/persist";
+                  };
+                };
+              };
+            };
+          };
+        };
+      };
+    };
+}

modules/nixos/boot/impermanence.nix

@@ -0,0 +1,77 @@
+{ inputs, ... }:
+{
+  flake.modules.nixos.boot =
+    {
+      config,
+      lib,
+      ...
+    }:
+    let
+      cfg = config.tnix.boot;
+    in
+    {
+      imports = [
+        inputs.impermanence.nixosModules.impermanence
+      ];
+
+      options.tnix.boot.impermanence = {
+        enable = lib.mkEnableOption "Enable impermanence";
+      };
+
+      config = lib.mkIf cfg.impermanence.enable {
+        programs.fuse.userAllowOther = true;
+        fileSystems."/persist".neededForBoot = true;
+        environment.persistence."/persist" = {
+          hideMounts = true;
+          directories = [
+            "/var/log"
+            "/var/lib"
+            "/etc/NetworkManager/system-connections"
+          ];
+          files = [
+            "/etc/ssh/ssh_host_ed25519_key"
+            "/etc/ssh/ssh_host_ed25519_key.pub"
+            "/etc/ssh/ssh_host_rsa_key"
+            "/etc/ssh/ssh_host_rsa_key.pub"
+          ];
+        };
+
+        boot.initrd.systemd = {
+          enable = true;
+
+          services.wipe-my-fs = {
+            wantedBy = [ "initrd.target" ];
+            after = [ "initrd-root-device.target" ];
+            before = [ "sysroot.mount" ];
+            unitConfig.DefaultDependencies = "no";
+            serviceConfig.Type = "oneshot";
+            script = ''
+              mkdir /btrfs_tmp
+              mount /dev/disk/by-partlabel/disk-primary-root /btrfs_tmp
+
+              if [[ -e /btrfs_tmp/root ]]; then
+                  mkdir -p /btrfs_tmp/old_roots
+                  timestamp=$(date --date="@$(stat -c %Y /btrfs_tmp/root)" "+%Y-%m-%-d_%H:%M:%S")
+                  mv /btrfs_tmp/root "/btrfs_tmp/old_roots/$timestamp"
+              fi
+
+              delete_subvolume_recursively() {
+                  IFS=$'\n'
+                  for i in $(btrfs subvolume list -o "$1" | cut -f 9- -d ' '); do
+                      delete_subvolume_recursively "/btrfs_tmp/$i"
+                  done
+                  btrfs subvolume delete "$1"
+              }
+
+              for i in $(find /btrfs_tmp/old_roots/ -maxdepth 1 -mtime +30); do
+                  delete_subvolume_recursively "$i"
+              done
+
+              btrfs subvolume create /btrfs_tmp/root
+              umount /btrfs_tmp
+            '';
+          };
+        };
+      };
+    };
+}

modules/nixos/boot/loader.nix

@@ -1,5 +1,8 @@
 {
   flake.modules.nixos.boot = {
-    boot.loader.efi.canTouchEfiVariables = true;
+    boot.loader = {
+      timeout = 1;
+      efi.canTouchEfiVariables = true;
+    };
   };
 }

modules/nixos/boot/misc.nix

@@ -0,0 +1,11 @@
+{
+  flake.modules.nixos.boot =
+    { pkgs, ... }:
+    {
+      boot = {
+        consoleLogLevel = 0;
+        initrd.verbose = false;
+        kernelPackages = pkgs.linuxPackages_zen;
+      };
+    };
+}

modules/nixos/desktop/ly.nix

@@ -3,7 +3,7 @@
     services.displayManager.ly = {
       enable = true;
       settings = {
-        # session_log = "null";
+        session_log = "null";
       };
     };
   };

modules/nixos/hardware/audio.nix

@@ -1,6 +1,5 @@
 {
-  flake.modules.nixos.desktop = {
-
+  flake.modules.nixos.hardware = {
     security.rtkit.enable = true;
 
     services.pipewire = {

modules/nixos/hardware/bluetooth.nix

@@ -0,0 +1,7 @@
+{
+  flake.modules.nixos.hardware = {
+    hardware.bluetooth = {
+      enable = true;
+    };
+  };
+}

modules/nixos/hardware/graphics.nix

@@ -1,5 +1,5 @@
 {
-  flake.modules.nixos.desktop = {
+  flake.modules.nixos.hardware = {
     hardware = {
       graphics = {
         enable = true;

modules/nixos/networking/ssh.nix

@@ -8,6 +8,10 @@
     with lib;
     let
       cfg = config.tnix.networking.openssh;
+
+      # Sops needs acess to the keys before the persist dirs are even mounted; so
+      # just persisting the keys won't work, we must point at /persist
+      hasOptinPersistence = config.tnix.boot.impermanence.enable;
     in
     {
       options.tnix.networking.openssh = {
@@ -59,6 +63,13 @@
             ClientAliveCountMax = 5;
             ClientAliveInterval = 60;
           };
+
+          hostKeys = [
+            {
+              path = "${lib.optionalString hasOptinPersistence "/persist"}/etc/ssh/ssh_host_ed25519_key";
+              type = "ed25519";
+            }
+          ];
         };
       };
     };

modules/nixos/services/cyber-tux.nix

@@ -0,0 +1,105 @@
+{
+  flake.modules.nixos.services =
+    {
+      config,
+      lib,
+      pkgs,
+      ...
+    }:
+    with lib;
+    let
+      cfg = config.tnix.services.cyber-tux;
+    in
+    {
+      options.tnix.services.cyber-tux = {
+        enable = mkEnableOption "CyberTux Discord bot";
+
+        user = mkOption {
+          type = types.str;
+          default = "cyber-tux";
+          description = "User under which the CyberTux service runs.";
+        };
+
+        group = mkOption {
+          type = types.str;
+          default = "cyber-tux";
+          description = "Group under which the CyberTux service runs.";
+        };
+
+        dataDir = mkOption {
+          type = types.path;
+          default = "/var/lib/cyber-tux";
+          description = "Directory where CyberTux stores its data.";
+        };
+
+        environmentFile = mkOption {
+          type = types.path;
+          description = "Environment file containing the Discord bot token.";
+        };
+      };
+
+      config = mkIf cfg.enable {
+        systemd.services.cyber-tux = {
+          description = "CyberTux Discord bot";
+          after = [ "network.target" ];
+          wantedBy = [ "multi-user.target" ];
+
+          serviceConfig = {
+            Type = "simple";
+            User = cfg.user;
+            Group = cfg.group;
+            EnvironmentFile = cfg.environmentFile;
+            ExecStart = getExe pkgs.cyber-tux;
+            Restart = "always";
+            RestartSec = 5;
+            WorkingDirectory = cfg.dataDir;
+            StateDirectory = baseNameOf cfg.dataDir;
+            StateDirectoryMode = "0700";
+
+            LockPersonality = true;
+            MemoryDenyWriteExecute = true;
+            NoNewPrivileges = true;
+            PrivateDevices = true;
+            PrivateIPC = true;
+            PrivateTmp = true;
+            PrivateUsers = true;
+            ProtectClock = true;
+            ProtectControlGroups = true;
+            ProtectHome = true;
+            ProtectHostname = true;
+            ProtectKernelLogs = true;
+            ProtectKernelModules = true;
+            ProtectKernelTunables = true;
+            ProtectProc = "invisible";
+            ProtectSystem = "strict";
+            RestrictNamespaces = [
+              "uts"
+              "ipc"
+              "pid"
+              "user"
+              "cgroup"
+            ];
+            RestrictRealtime = true;
+            RestrictSUIDSGID = true;
+            SystemCallArchitectures = "native";
+            SystemCallFilter = [ "@system-service" ];
+            UMask = "0077";
+          };
+        };
+
+        users.users = mkIf (cfg.user == "cyber-tux") {
+          ${cfg.user} = {
+            isSystemUser = true;
+            group = cfg.group;
+            description = "CyberTux service user";
+            home = cfg.dataDir;
+            createHome = true;
+          };
+        };
+
+        users.groups = mkIf (cfg.group == "cyber-tux") {
+          ${cfg.group} = { };
+        };
+      };
+    };
+}